(*
 * LANGUAGE    : ANS Forth
 * PROJECT     : Forth Environments
 * DESCRIPTION : Julia fractal of c+z^3 with special boundary
 * CATEGORY    : Graphic example
 * AUTHOR      : Marcel Hendrix 
 * LAST CHANGE : Tuesday, December 30, 2003 4:56 PM, Marcel Hendrix 
 *)



        NEEDS -miscutil
	NEEDS -graphics

        REVISION -julcell "ÄÄÄ Julia c+z^3         Version 1.00 ÄÄÄ"

	PRIVATES


DOC
(*
 Julia fractal of c+z^3 with special boundary
*)
ENDDOC

-- Parameters 
-0.6525e  FVALUE Aa
 0.34e    FVALUE Bb
 0.2e     FVALUE Dd
 1.0e     FVALUE delH
 1.0e	  FVALUE delV
   9       VALUE amp

-- Globals
       0. DVALUE @XY    PRIVATE

: COLORIZE ( ix -- ) 
		3 * palette + 
		C@+ amp * >S
		C@+ amp * >< S> OR >S
		C@  amp * #16 LSHIFT S> OR >S
		@XY S> SET-MDOT ;

: INNERLOOP ( x y -- ) 
		2DUP TO @XY UNSCALE? DROP 0e 0e FLOCALS| t1 t2 yy xx |
		#40  1 DO  xx FABS Dd F*  yy FABS F+  20e F>
			   yy FABS Dd F*  xx FABS F+  20e F> 
			   AND IF  I COLORIZE  LEAVE  ENDIF
			   xx FSQR  yy FSQR 3e F* F- xx F*  Aa F+  xx FSWAP TO xx
			      FSQR 3e F*  yy FSQR F- yy F*  Bb F+ 	    TO yy
		     LOOP ;P

: COMPUTE	TEXTMODE? DUP >R IF GRAPHICS ENDIF  
		0 0 Xmax Ymax  delH FNEGATE delV FNEGATE delH delV  SET-GWINDOW	GCLEAR 
		#40 RANDOMPALETTE
		RESET-MDOTS
		  Xmax 0 ?DO  Ymax 0 ?DO  J I INNERLOOP  LOOP  LOOP
		FLUSH-MDOTS
		R> IF  TEXT  ENDIF ;

:ABOUT		CR ." Type COMPUTE for a Julia fractal."
		CR
		CR ."  1.4e TO delH  1.4e TO delV -- zoom picture "
		CR ."  9 TO amp  COMPUTE          -- influence contrast "
		CR
		CR ." Example parameters: "
		CR ." -1.754878e TO Aa  0e        TO Bb COMPUTE "
		CR ." -1.543689e TO Aa  0e        TO Bb COMPUTE " 
		CR ." 5e 4e F/   TO Aa  0e        TO Bb COMPUTE " 
		CR ." -1e        TO Aa  0e        TO Bb COMPUTE " 
		CR ." -0.75e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.3e      TO Aa  0e        TO Bb COMPUTE "
		CR ." -0.122561e TO Aa  0.744862e TO Bb COMPUTE "
		CR ." -0.101096e TO Aa  0.956287e TO Bb COMPUTE "
		CR ."  0.11e     TO Aa  0.67e     TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0.25e     TO Bb COMPUTE "
		CR ." -0.318472e TO Aa  0.041257e TO Bb COMPUTE " ;

                .ABOUT -julcell CR
		DEPRIVE

                              (* End of Source *)