(*
 * LANGUAGE    : ANS Forth
 * PROJECT     : Forth Environments
 * DESCRIPTION : Mandelbrot set of c + z - exp(z)
 * CATEGORY    : Graphic example
 * AUTHOR      : Marcel Hendrix 
 * LAST CHANGE : Tuesday, December 30, 2003 9:09 PM, Marcel Hendrix 
 *)



        NEEDS -miscutil
	NEEDS -graphics

        REVISION -manexp "ÄÄÄ Mandelbrot c+z-exp  Version 1.00 ÄÄÄ"

	PRIVATES


DOC
(*
 Mandelbrot set of c + z - exp(z)
*)
ENDDOC

-- Parameters 
    4e FVALUE Aa
    0e FVALUE Bb
    4e FVALUE delH
 2.15e FVALUE delV
    6   VALUE amp

-- Globals
       0. DVALUE @XY    PRIVATE

: COLORIZE ( ix -- ) 
		3 * palette + 
		C@+ amp * >S
		C@+ amp * >< S> OR >S
		C@  amp * #16 LSHIFT S> OR >S
		@XY S> SET-MDOT ;

: INNERLOOP ( x y -- ) 
		2DUP TO @XY UNSCALE? DROP FLOCALS| yy xx |
		xx Aa F+ yy Bb F+ 0e 0e 0e 0e FLOCALS| y1 x1 vv uu b1 a1 |
		a1 F1- FSQR  b1 FSQR F+ 1e F< IF  EXIT  ENDIF
		CLEAR xx  CLEAR yy
		 #20 1 DO  xx 10e F> IF  I COLORIZE LEAVE  ENDIF
		 	   xx FEXP TO uu
			   a1 xx F+  yy FCOS uu F* F- TO x1
			   b1 yy F+  yy FSIN uu F* F- TO y1
			   xx x1 F- FSQR  yy y1 F- FSQR F+ 1e-4 F< ?LEAVE
			   x1 TO xx  y1 TO yy
		     LOOP ;P

: COMPUTE	TEXTMODE? DUP >R IF GRAPHICS ENDIF  
		0 0 Xmax Ymax  delH FNEGATE delV FNEGATE 0e delV SET-GWINDOW GCLEAR 
		#20 RANDOMPALETTE
		RESET-MDOTS
		  Xmax 0 ?DO  Ymax 0 ?DO  J I INNERLOOP  LOOP  LOOP
		FLUSH-MDOTS
		R> IF  TEXT  ENDIF ;

:ABOUT		CR ." Type COMPUTE for a Mandelbot fractal."
		CR
		CR ."  1.4e TO delH  1.4e TO delV -- zoom picture "
		CR ."  9 TO amp  COMPUTE          -- influence contrast " ;

                .ABOUT -manexp CR
		DEPRIVE

                              (* End of Source *)