(*
 * LANGUAGE    : ANS Forth
 * PROJECT     : Forth Environments
 * DESCRIPTION : Mandelbrot set of c + pi - sin(z)
 * CATEGORY    : Graphic example
 * AUTHOR      : Marcel Hendrix 
 * LAST CHANGE : Wednesday, December 31, 2003 2:02 AM, Marcel Hendrix 
 *)



        NEEDS -miscutil
	NEEDS -graphics

        REVISION -mansin2 "ÄÄÄ Mandelbrot c+pi-sin Version 1.00 ÄÄÄ"

	PRIVATES


DOC
(*
 Mandelbrot set of c + pi - sin(z)
*)
ENDDOC

-- Parameters 
         0e FVALUE Aa
	 0e FVALUE Bb
         PI FVALUE delH
         PI FVALUE delV
         9   VALUE amp

-- Globals
       0. DVALUE @XY    PRIVATE

: COLORIZE ( ix -- ) 
		3 * palette + 
		C@+ amp * >S
		C@+ amp * >< S> OR >S
		C@  amp * #16 LSHIFT S> OR >S
		@XY S> SET-MDOT ;

: INNERLOOP ( x y -- ) 
		2DUP TO @XY UNSCALE? DROP FLOCALS| yy xx |
		xx Aa F+ yy Bb F+  0e 0e  0e 0e  0e 0e FLOCALS| sh ch ss cs y1 x1 b1 a1 |
		DelH F2/ TO xx  CLEAR yy
		 #40 1 DO  yy FABS 12e F> IF  I COLORIZE LEAVE  ENDIF
		 	   yy FEXP  FDUP 1/F ( u v ) F2DUP F+ F2/ TO ch  F- F2/ TO sh
			   xx FSINCOS TO cs TO ss
			   ss ch F* delH F*  a1 F+  TO x1
			   cs sh F* delV F*  b1 F+  TO y1
			   xx x1 F- FABS  yy y1 F- FABS F+ 1e-3 F< ?LEAVE
			   x1 TO xx  y1 TO yy
		     LOOP ;P

: COMPUTE	TEXTMODE? DUP >R IF GRAPHICS ENDIF  
		0 0 Xmax Ymax  delH FNEGATE delV FNEGATE delH delV SET-GWINDOW GCLEAR 
		#40 RANDOMPALETTE
		RESET-MDOTS
		  Xmax 0 ?DO  Ymax 0 ?DO  J I INNERLOOP  LOOP  LOOP
		FLUSH-MDOTS
		R> IF  TEXT  ENDIF ;

:ABOUT		CR ." Type COMPUTE for a Mandelbot fractal."
		CR
		CR ."  1.4e TO delH  1.4e TO delV -- zoom picture "
		CR ."  9 TO amp  COMPUTE          -- influence contrast " 
		CR
		CR ." -1.754878e TO Aa  0e        TO Bb COMPUTE "
		CR ." -1.543689e TO Aa  0e        TO Bb COMPUTE " 
		CR ." 5e 4e F/   TO Aa  0e        TO Bb COMPUTE " 
		CR ." -1e        TO Aa  0e        TO Bb COMPUTE " 
		CR ." -0.75e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.3e      TO Aa  0e        TO Bb COMPUTE "
		CR ." -0.122561e TO Aa  0.744862e TO Bb COMPUTE "
		CR ." -0.101096e TO Aa  0.956287e TO Bb COMPUTE "
		CR ."  0.11e     TO Aa  0.67e     TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0.25e     TO Bb COMPUTE "
		CR ." -0.318472e TO Aa  0.041257e TO Bb COMPUTE " ;

                .ABOUT -mansin2 CR
		DEPRIVE

                              (* End of Source *)